レジストリをバックアップ(エクスポート)

2010 年 2 月 20 日 | カテゴリー: ソフトウェア | タグ: ,

レジストリをregファイルとして手軽にバックアップ出来るフリーソフトを探していたのですが、なかなか良さそうなものが見つかりませんでした。あんまり需要ないのかな?それとも私が見つけられなかったのか。。。

そんなわけでレジストリをバックアップするためのバッチファイルを作りました。

Registry_Backup←Download

Windows 7, Vista, XPにて動作確認済み。

zipを解凍し、regback.batを右クリックメニューから編集を選択してください。ファイルの上部に設定箇所があるので、個々の環境にあわせ編集してください。

zip圧縮する場合は別途7za.exeが必要になります。7za.exeはこちらからダウンロード出来ます。

[bash]
@echo off
rem 設定ここから
rem 保存先を指定してください.
rem 保存先にregファイルがあると削除してしまいます.
rem フォルダ名の最後に\をつけないでください.
set savefolder=D:\Users\Application Data\Registry_Backup
rem zip圧縮する場合は1,しない場合は0.
rem zip圧縮する場合はbinフォルダに7za.exeを入れる必要があります.
set zip=0
rem 設定ここまで
set YYYYMMDD=%DATE:/=%
set HHMM=%TIME::=%
set HHMM=%HHMM:~0,4%
set HHMM=%HHMM: =0%
set BIN=%~dp0bin
cd /d %savefolder%
if errorlevel 1 goto errorsvf
echo 不要なregファイルが保存先にあるか確認中…
del /p *.reg
echo %savefolder%にレジストリを保存します.
echo レジストリのエクスポートを開始します.
echo HKEY_CLASSES_ROOTをエクスポート中…
REG EXPORT HKCR EXP_HKCR.reg
echo HKEY_CURRENT_USERをエクスポート中…
REG EXPORT HKCU EXP_HKCU.reg
echo HKEY_LOCAL_MACHINEをエクスポート中…
REG EXPORT HKLM EXP_HKLM.reg
echo HKEY_USERSをエクスポート中…
REG EXPORT HKU EXP_HKU.reg
echo HKEY_CURRENT_CONFIGをエクスポート中…
REG EXPORT HKCC EXP_HKCC.reg
if "%zip%"=="1" goto zip
if "%zip%"=="0" goto folder
:folder
echo エクスポートしたレジストリをフォルダに移動します.
md %YYYYMMDD%%HHMM%
copy *.reg %YYYYMMDD%%HHMM%
del *.reg
goto end
:zip
echo エクスポートしたレジストリをzip圧縮します.
"%BIN%\7za.exe" a -tzip %YYYYMMDD%%HHMM%.zip *.reg
if errorlevel 1 goto errorzip
del *.reg
goto end
:errorsvf
echo 保存先のフォルダが見つかりませんでした.
echo 設定を再確認してください.
goto end
:errorzip
del *.reg
echo 7za.exeが見つからなかったか,正常に動作しませんでした.
echo 7za.exeがbinフォルダにあるか確認してください.
goto end
:end
pause
[/bash]
修正
2010/02/21:cd /d %savefolder%

コメントはまだありません。